[mlir] Test vector.to_elements to spirv conversion.

Author: amd-eochoalo

mlir/test/Conversion/ConvertToSPIRV/vector-sizes.mlir

@@ -0,0 +1,67 @@
+// RUN: mlir-opt -test-convert-to-spirv="run-signature-conversion=false run-vector-unrolling=true" -split-input-file %s | FileCheck %s
+
+// COM: This file tests the current behaviour of the SignatureConversion
+// COM: and the unrolling of vector.to_elements to vectors of valid SPIR-V
+// COM: sizes.
+
+// COM: vector's of rank 1 and size 1 will be changed
+// COM: to scalars. Since vector.to_elements will also produce
+// COM: a scalar, we expect the vector.to_elements to be folded
+// COM: away. Please note that even if run-signature-conversion=false
+// COM: The pattern FuncOpConversion will still run and change parameters
+// COM: which fit this constraint.
+
+// CHECK-LABEL: spirv.func @vec_size_1
+// CHECK-SAME: (%[[ARG0:.+]]: f32)
+func.func @vec_size_1(%arg0: vector<1xf32>) -> (f32) {
+  // CHECK-NEXT: spirv.ReturnValue %[[ARG0]] : f32
+  %0:1 = vector.to_elements %arg0 : vector<1xf32>
+  return %0#0 : f32
+}
+
+// -----
+
+// COM: vector's of rank 2, 3, 4 are allowed by SPIR-V.
+// So they remain unchanged. FuncOpConversion will still
+// run, but the signature converter will not convert these vectors.
+
+// CHECK-LABEL: spirv.func @vec_size_2
+// CHECK-SAME: (%[[ARG0:.+]]: vector<2xf32>)
+func.func @vec_size_2(%arg0: vector<2xf32>) -> (f32) {
+  // COM: A single result type is enforced by the semantics
+
+  // CHECK-NEXT: %[[VAL:.+]] = spirv.CompositeExtract %[[ARG0]][0 : i32] : vector<2xf32>
+  %0:2 = vector.to_elements %arg0 : vector<2xf32>
+
+  // CHECK-NEXT: spirv.ReturnValue %[[VAL]]
+  return %0#0 : f32
+}
+
+// -----
+
+// COM: vector of rank 5 is the first one that doesn't fit
+// COM: into SPIR-V's vectors.
+
+// COM: run-signature-conversion=false means that
+// COM: this vector will not be unrolled.
+
+// CHECK-LABEL: func.func @vec_size_5
+// CHECK-SAME: (%[[ARG0:.+]]: vector<5xf32>)
+func.func @vec_size_5(%arg0: vector<5xf32>) -> (f32) {
+
+  // CHECK-NEXT: %[[VAL:.+]] = vector.extract_strided_slice %[[ARG0]] {offsets = [0], sizes = [1], strides = [1]} : vector<5xf32> to vector<1xf32>
+
+  // COM: We have the following comment in VectorConvertToElementOp
+  // COM:
+  // COM:     // Input vectors of size 1 are converted to scalars by the type converter.
+  // COM:     // We cannot use `spirv::CompositeExtractOp` directly in this case.
+  // COM:     // For a scalar source, the result is just the scalar itself.
+  // COM:
+  // COM: Which in this case means an unrealized conversion cast.
+
+  // CHECK-NEXT: %[[RETVAL:.+]] = builtin.unrealized_conversion_cast %[[VAL]] : vector<1xf32> to f32
+  %0:5 = vector.to_elements %arg0 : vector<5xf32>
+
+  // CHECK-NEXT: spirv.ReturnValue %[[RETVAL]] : f32
+  return %0#0 : f32
+}