Add new type of process wrapper test

Author: UebelAndre

rust/private/rust.bzl

@@ -1355,12 +1355,22 @@ _rust_binary_without_process_wrapper_transition = transition(
     ],
 )
 
+_RustBuiltWithoutProcessWrapperInfo = provider(
+    doc = "A provider identifying the target having been built using a `*_without_process_wrapper` rule variant.",
+    fields = {},
+)
+
+def _rust_binary_without_process_wrapper_impl(ctx):
+    providers = _rust_binary_impl(ctx)
+    return providers + [_RustBuiltWithoutProcessWrapperInfo()]
+
 # Provides an internal rust_{binary,library} to use that we can use to build the process
 # wrapper, this breaks the dependency of rust_* on the process wrapper by
 # setting it to None, which the functions in rustc detect and build accordingly.
 rust_binary_without_process_wrapper = rule(
-    implementation = _rust_binary_impl,
-    provides = COMMON_PROVIDERS,
+    implementation = _rust_binary_without_process_wrapper_impl,
+    doc = "A variant of `rust_binary` that uses a minimal process wrapper for `Rustc` actions.",
+    provides = COMMON_PROVIDERS + [_RustBuiltWithoutProcessWrapperInfo],
     attrs = _common_attrs_for_binary_without_process_wrapper(_common_attrs | _rust_binary_attrs),
     cfg = _rust_binary_without_process_wrapper_transition,
     executable = True,
@@ -1371,9 +1381,14 @@ rust_binary_without_process_wrapper = rule(
     ],
 )
 
+def _rust_library_without_process_wrapper_impl(ctx):
+    providers = _rust_library_impl(ctx)
+    return providers + [_RustBuiltWithoutProcessWrapperInfo()]
+
 rust_library_without_process_wrapper = rule(
-    implementation = _rust_library_impl,
-    provides = COMMON_PROVIDERS,
+    implementation = _rust_library_without_process_wrapper_impl,
+    doc = "A variant of `rust_library` that uses a minimal process wrapper for `Rustc` actions.",
+    provides = COMMON_PROVIDERS + [_RustBuiltWithoutProcessWrapperInfo],
     attrs = dict(_common_attrs_for_binary_without_process_wrapper(_common_attrs).items()),
     fragments = ["cpp"],
     toolchains = [
@@ -1382,6 +1397,39 @@ rust_library_without_process_wrapper = rule(
     ],
 )
 
+def _test_attrs_for_binary_without_process_wrapper(attrs):
+    new_attrs = {}
+    new_attrs.update(attrs)
+
+    # Require that `crate` has the correct internal provider.
+    new_attrs["crate"] = attr.label(
+        mandatory = False,
+        providers = [_RustBuiltWithoutProcessWrapperInfo],
+        doc = dedent("""\
+            Target inline tests declared in the given crate
+
+            These tests are typically those that would be held out under
+            `#[cfg(test)]` declarations.
+        """),
+    )
+
+    return new_attrs
+
+rust_test_without_process_wrapper_test = rule(
+    implementation = _rust_test_impl,
+    doc = "Unlike other `*_without_process_wrapper` rules, this rule does use the process wrapper but requires it's dependencies were not built with one.",
+    provides = COMMON_PROVIDERS,
+    attrs = _test_attrs_for_binary_without_process_wrapper(_common_attrs | _rust_test_attrs),
+    executable = True,
+    cfg = _rust_binary_without_process_wrapper_transition,
+    fragments = ["cpp"],
+    test = True,
+    toolchains = [
+        str(Label("//rust:toolchain_type")),
+        config_common.toolchain_type("@bazel_tools//tools/cpp:toolchain_type", mandatory = False),
+    ],
+)
+
 def _rust_test_transition_impl(settings, attr):
     return {
         "//command_line_option:platforms": str(attr.platform) if attr.platform else settings["//command_line_option:platforms"],

util/process_wrapper/BUILD.bazel

@@ -1,8 +1,7 @@
 load("@bazel_skylib//lib:selects.bzl", "selects")
-load("//rust:defs.bzl", "rust_test")
 
 # buildifier: disable=bzl-visibility
-load("//rust/private:rust.bzl", "rust_binary_without_process_wrapper")
+load("//rust/private:rust.bzl", "rust_binary_without_process_wrapper", "rust_test_without_process_wrapper_test")
 load("//util/process_wrapper/private:bootstrap_process_wrapper.bzl", "bootstrap_process_wrapper")
 
 config_setting(
@@ -50,7 +49,7 @@ rust_binary_without_process_wrapper(
     ],
 )
 
-rust_test(
+rust_test_without_process_wrapper_test(
     name = "process_wrapper_test",
     crate = ":process_wrapper",
     edition = "2018",